{
  description = "Nix PR status checker";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    poetry2nix = {
      url = "github:nix-community/poetry2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      poetry2nix,
    }:
    {
      overlays.default = final: prev: {
        nixprstatus = self.packages.${prev.system}.default;
      };
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        # see https://github.com/nix-community/poetry2nix/tree/master#api for more functions and examples.
        pkgs = nixpkgs.legacyPackages.${system};
        inherit (poetry2nix.lib.mkPoetry2Nix { inherit pkgs; }) mkPoetryApplication defaultPoetryOverrides;
      in
      {
        packages = {
          nixprstatus = mkPoetryApplication {
            projectDir = pkgs.lib.sourceFilesBySuffices ./. [
              "pyproject.toml"
              "poetry.lock"
              "README.md"
              ".py"
            ];
            python = pkgs.python312;
            nativeBuildInputs = [ pkgs.installShellFiles ];
            postInstall = ''
              installShellCompletion --cmd nixprstatus \
                --bash <($out/bin/nixprstatus --show-completion bash) \
                --zsh <($out/bin/nixprstatus --show-completion zsh) \
                --fish <($out/bin/nixprstatus --show-completion fish)
            '';
          };
          default = self.packages.${system}.nixprstatus;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ self.packages.${system}.nixprstatus ];
          packages = [
            pkgs.poetry
          ];
        };
      }
    );
}