diff --git a/home/packages/default.nix b/home/packages/default.nix
index 2375158..7af3fc3 100644
--- a/home/packages/default.nix
+++ b/home/packages/default.nix
@@ -117,5 +117,7 @@ in
     # From nix-packages flake
     path-of-building-beta
     awakened-poe-trade
+
+    (pkgs.callPackage ./vintagestory.nix { })
   ];
 }
diff --git a/home/packages/vintagestory.nix b/home/packages/vintagestory.nix
new file mode 100644
index 0000000..cab6c68
--- /dev/null
+++ b/home/packages/vintagestory.nix
@@ -0,0 +1,105 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  makeDesktopItem,
+  copyDesktopItems,
+  xorg,
+  gtk2,
+  sqlite,
+  openal,
+  cairo,
+  libGLU,
+  SDL2,
+  freealut,
+  libglvnd,
+  pipewire,
+  libpulseaudio,
+  dotnet-runtime_8,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vintagestory";
+  version = "1.20.0-rc.6";
+
+  src = fetchurl {
+    url = "https://cdn.vintagestory.at/gamefiles/unstable/vs_client_linux-x64_${version}.tar.gz";
+    hash = "sha256-JxyQrZrAmMkUy28JUak0BHHpuGEb2fbxNrtOGVKGhOQ=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  buildInputs = [ dotnet-runtime_8 ];
+
+  runtimeLibs = lib.makeLibraryPath (
+    [
+      gtk2
+      sqlite
+      openal
+      cairo
+      libGLU
+      SDL2
+      freealut
+      libglvnd
+      pipewire
+      libpulseaudio
+    ]
+    ++ (with xorg; [
+      libX11
+      libXi
+      libXcursor
+    ])
+  );
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "vintagestory";
+      desktopName = "Vintage Story";
+      exec = "vintagestory";
+      icon = "vintagestory";
+      comment = "Innovate and explore in a sandbox world";
+      categories = [ "Game" ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/vintagestory $out/bin $out/share/pixmaps $out/share/fonts/truetype
+    cp -r * $out/share/vintagestory
+    cp $out/share/vintagestory/assets/gameicon.xpm $out/share/pixmaps/vintagestory.xpm
+    cp $out/share/vintagestory/assets/game/fonts/*.ttf $out/share/fonts/truetype
+
+    runHook postInstall
+  '';
+
+  preFixup =
+    ''
+      makeWrapper ${dotnet-runtime_8}/bin/dotnet $out/bin/vintagestory \
+        --prefix LD_LIBRARY_PATH : "${runtimeLibs}" \
+        --add-flags $out/share/vintagestory/Vintagestory.dll
+      makeWrapper ${dotnet-runtime_8}/bin/dotnet $out/bin/vintagestory-server \
+        --prefix LD_LIBRARY_PATH : "${runtimeLibs}" \
+        --add-flags $out/share/vintagestory/VintagestoryServer.dll
+    ''
+    + ''
+      find "$out/share/vintagestory/assets/" -not -path "*/fonts/*" -regex ".*/.*[A-Z].*" | while read -r file; do
+        local filename="$(basename -- "$file")"
+        ln -sf "$filename" "''${file%/*}"/"''${filename,,}"
+      done
+    '';
+
+  meta = with lib; {
+    description = "In-development indie sandbox game about innovation and exploration";
+    homepage = "https://www.vintagestory.at/";
+    license = licenses.unfree;
+    maintainers = with maintainers; [
+      artturin
+      gigglesquid
+    ];
+  };
+}
diff --git a/hosts/gunter/ollama.nix b/hosts/gunter/ollama.nix
index bd9385e..305078c 100644
--- a/hosts/gunter/ollama.nix
+++ b/hosts/gunter/ollama.nix
@@ -5,7 +5,7 @@
     acceleration = "cuda";
   };
   services.open-webui = {
-    enable = true;
+    enable = lib.warn "open-webui disabled due to build failure" false;
     environment = {
       DO_NOT_TRACK = "True";
       SCARF_NO_ANALYTICS = "True";