nixos/flake.nix

{
  description = "Torjus nixos config flake";

  inputs = {
    # nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-23.11";
    nixpkgs-unstable.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager?ref=release-23.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sops-nix.url = "github:Mic92/sops-nix";
    notlistener.url = "git+https://git.t-juice.club/torjus/notlistener?ref=master";
    ghettoptt.url = "git+https://git.t-juice.club/torjus/ghettoptt?ref=master";
  };

  outputs =
    { self
    , nixpkgs
    , nixpkgs-unstable
    , sops-nix
    , notlistener
    , ghettoptt
    , ...
    }@inputs:
    let
      system = "x86_64-linux";
      user = "torjus";
      overlay-unstable = final: prev: {
        unstable = import nixpkgs-unstable {
          inherit system;
          config.allowUnfree = true;
        };
      };
    in
    {
      nixosConfigurations = {
        prismo = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit inputs self user; };
          modules = [ ./hosts/prismo ];
        };
        magicman = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit inputs self user; };
          modules = [
            ({ config, pkgs, ... }: {
              nixpkgs.overlays = [
                overlay-unstable
                ghettoptt.overlays.default
              ];
            })
            ./hosts/magicman
            sops-nix.nixosModules.sops
          ];
        };
        gunter = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit inputs self user sops-nix; };
          modules = [
            ({ config, pkgs, ... }: {
              nixpkgs.overlays = [
                overlay-unstable
                notlistener.overlays.default
                ghettoptt.overlays.default
              ];
            })
            ./hosts/gunter
            sops-nix.nixosModules.sops
          ];
        };
      };
    };
}