{
  description = "Various packages not in nixpkgs";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs =
    { self, nixpkgs }:
    let
      allSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems =
        f:
        nixpkgs.lib.genAttrs allSystems (
          system:
          f {
            pkgs = import nixpkgs {
              inherit system;
              config.allowUnfree = true;
            };
          }
        );
    in
    {
      overlays = {
        default = final: prev: {
          inherit (self.packages.${prev.system})
            awakened-poe-trade
            path-of-building-beta
            vintagestory-unstable
            ;
        };
        awakened-poe-trade = final: prev: {
          inherit (self.packages.${prev.system}) awakened-poe-trade;
        };
        path-of-building-beta = final: prev: {
          inherit (self.packages.${prev.system}) path-of-building-beta;
        };
        vintagestory-unstable = final: prev: {
          inherit (self.packages.${prev.system}) vintagestory-unstable;
        };
        noita-entangled-worlds = final: prev: {
          inherit (self.packages.${prev.system}) noita-entangled-worlds;
        };
        poe-sidekick = final: prev: {
          inherit (self.packages.${prev.system}) poe-sidekick;
        };
        poe-sidekick-web = final: prev: {
          inherit (self.packages.${prev.system}) poe-sidekick-web;
        };
      };

      formatter = forAllSystems ({ pkgs, ... }: pkgs.nixfmt-tree);

      devShells = forAllSystems (
        { pkgs }:
        {
          default = pkgs.mkShell {
            packages = [
              pkgs.nixfmt-tree
              pkgs.statix
            ];
          };
        }
      );

      packages = forAllSystems (
        { pkgs }:
        {
          awakened-poe-trade = pkgs.callPackage ./pkgs/awakened-poe-trade { };
          path-of-building-beta = pkgs.qt6Packages.callPackage ./pkgs/path-of-building-beta { };
          path-of-building-poe2 = pkgs.qt6Packages.callPackage ./pkgs/path-of-building-poe2 { };
          vintagestory-unstable = pkgs.callPackage ./pkgs/vintagestory { };
          noita-entangled-worlds = pkgs.callPackage ./pkgs/noita-entangled-worlds { };
          poe-sidekick = pkgs.callPackage ./pkgs/poe-sidekick { };
          poe-sidekick-web = pkgs.callPackage ./pkgs/poe-sidekick/web.nix { };
        }
      );
    };
}