{
  alsa-lib,
  gtk3,
  fetchFromGitHub,
  rustPlatform,
  openssl,
  pkg-config,
  jack2,
  python3,
  cmake,
  libopus,
  steam-run,
  writeShellApplication,
  lib,
}:
let
  entangled = rustPlatform.buildRustPackage rec {
    pname = "noita-entangled-worlds-proxy";
    version = "v1.5.3";

    src = fetchFromGitHub {
      owner = "IntQuant";
      repo = "noita_entangled_worlds";
      rev = version;
      hash = "sha256-frrpD0aWTeDbZYtp15R+quUUAZf7OvHlbSLtGJJtAqk=";
    };

    sourceRoot = "${src.name}/noita-proxy";

    useFetchCargoVendor = true;
    cargoHash = "sha256-TzUS6d6PopgGf2i1yVaXaXdzNrvfSz+Gv67BAtxYmb4=";
    buildInputs = [
      gtk3
      openssl
      jack2
      alsa-lib
      libopus
    ];
    nativeBuildInputs = [
      pkg-config
      python3
      cmake
    ];
    preInstall = ''
      mkdir -p $out/share/lib64/noita-proxy
      cp -r ${src}/redist/libsteam_api.so $out/share/lib64/noita-proxy
    '';
    checkFlags = [
      # reason for disabling test
      "--skip=bookkeeping::releases::test::release_assets"
    ];
  };
in
writeShellApplication {
  name = "noita-proxy-${entangled.version}";
  runtimeInputs = [
    entangled
    steam-run
  ];
  text = ''
    export LD_PRELOAD=${entangled}/share/lib64/noita-proxy/libsteam_api.so
    exec steam-run "${entangled}/bin/noita-proxy" "$@"
  '';
}