poe-sidekick: add package

Flake lock file updates:

• Updated input 'nixpkgs':
    'github:NixOS/nixpkgs/ed4a395ea001367c1f13d34b1e01aa10290f67d6?narHash=sha256-jG/%2BMvjVY7SlTakzZ2fJ5dC3V1PrKKrUEOEE30jrOKA%3D' (2025-01-12)
  → 'github:NixOS/nixpkgs/2c8d3f48d33929642c1c12cd243df4cc7d2ce434?narHash=sha256-F7n4%2BKOIfWrwoQjXrL2wD9RhFYLs2/GGe/MQY1sSdlE%3D' (2025-04-02)

flake.lock

@@ -2,11 +2,11 @@
   "nodes": {
     "nixpkgs": {
       "locked": {
-        "lastModified": 1736701207,
-        "narHash": "sha256-jG/+MvjVY7SlTakzZ2fJ5dC3V1PrKKrUEOEE30jrOKA=",
+        "lastModified": 1743583204,
+        "narHash": "sha256-F7n4+KOIfWrwoQjXrL2wD9RhFYLs2/GGe/MQY1sSdlE=",
         "owner": "NixOS",
         "repo": "nixpkgs",
-        "rev": "ed4a395ea001367c1f13d34b1e01aa10290f67d6",
+        "rev": "2c8d3f48d33929642c1c12cd243df4cc7d2ce434",
         "type": "github"
       },
       "original": {

flake.nix

@@ -13,7 +13,16 @@
         "aarch64-darwin"
       ];
       forAllSystems =
-        f: nixpkgs.lib.genAttrs allSystems (system: f { pkgs = import nixpkgs { inherit system; }; });
+        f:
+        nixpkgs.lib.genAttrs allSystems (
+          system:
+          f {
+            pkgs = import nixpkgs {
+              inherit system;
+              config.allowUnfree = true;
+            };
+          }
+        );
     in
     {
       overlays = {
@@ -31,6 +40,15 @@
         vintagestory-unstable = final: prev: {
           vintagestory-unstable = self.packages.${prev.system}.vintagestory-unstable;
         };
+        noita-entangled-worlds = final: prev: {
+          noita-entangled-worlds = self.packages.${prev.system}.noita-entangled-worlds;
+        };
+        poe-sidekick = final: prev: {
+          poe-sidekick = self.packages.${prev.system}.poe-sidekick;
+        };
+        poe-sidekick-web = final: prev: {
+          poe-sidekick-web = self.packages.${prev.system}.poe-sidekick-web;
+        };
       };
 
       packages = forAllSystems (
@@ -38,7 +56,11 @@
         {
           awakened-poe-trade = pkgs.callPackage ./pkgs/awakened-poe-trade { };
           path-of-building-beta = pkgs.qt6Packages.callPackage ./pkgs/path-of-building-beta { };
+          path-of-building-poe2 = pkgs.qt6Packages.callPackage ./pkgs/path-of-building-poe2 { };
           vintagestory-unstable = pkgs.callPackage ./pkgs/vintagestory { };
+          noita-entangled-worlds = pkgs.callPackage ./pkgs/noita-entangled-worlds { };
+          poe-sidekick = pkgs.callPackage ./pkgs/poe-sidekick { };
+          poe-sidekick-web = pkgs.callPackage ./pkgs/poe-sidekick/web.nix { };
         }
       );
     };

pkgs/noita-entangled-worlds/default.nix

@@ -0,0 +1,64 @@
+{
+  alsa-lib,
+  gtk3,
+  fetchFromGitHub,
+  rustPlatform,
+  openssl,
+  pkg-config,
+  jack2,
+  python3,
+  cmake,
+  libopus,
+  steam-run,
+  writeShellApplication,
+  lib,
+}:
+let
+  entangled = rustPlatform.buildRustPackage rec {
+    pname = "noita-entangled-worlds-proxy";
+    version = "v1.5.3";
+
+    src = fetchFromGitHub {
+      owner = "IntQuant";
+      repo = "noita_entangled_worlds";
+      rev = version;
+      hash = "sha256-frrpD0aWTeDbZYtp15R+quUUAZf7OvHlbSLtGJJtAqk=";
+    };
+
+    sourceRoot = "${src.name}/noita-proxy";
+
+    useFetchCargoVendor = true;
+    cargoHash = "sha256-TzUS6d6PopgGf2i1yVaXaXdzNrvfSz+Gv67BAtxYmb4=";
+    buildInputs = [
+      gtk3
+      openssl
+      jack2
+      alsa-lib
+      libopus
+    ];
+    nativeBuildInputs = [
+      pkg-config
+      python3
+      cmake
+    ];
+    preInstall = ''
+      mkdir -p $out/share/lib64/noita-proxy
+      cp -r ${src}/redist/libsteam_api.so $out/share/lib64/noita-proxy
+    '';
+    checkFlags = [
+      # reason for disabling test
+      "--skip=bookkeeping::releases::test::release_assets"
+    ];
+  };
+in
+writeShellApplication {
+  name = "noita-proxy-${entangled.version}";
+  runtimeInputs = [
+    entangled
+    steam-run
+  ];
+  text = ''
+    export LD_PRELOAD=${entangled}/share/lib64/noita-proxy/libsteam_api.so
+    exec steam-run "${entangled}/bin/noita-proxy" "$@"
+  '';
+}

pkgs/path-of-building-beta/default.nix

@@ -19,8 +19,8 @@ let
     src = fetchFromGitHub {
       owner = "PathOfBuildingCommunity";
       repo = "PathOfBuilding";
-      rev = "f6d095a527017a1b2fd7b523d349f321bfdc2f58";
-      hash = "sha256-/pnirZSZBGpbVTdm/jmBzzdMdAiCcYlOiff7HQ2nINM=";
+      rev = "6a146e6c36c3549cce668c2b5424e04618ddd4a6";
+      hash = "sha256-q1WE2KpLvQqznOzbk39ThQGg7pvT7MES58uizpz+/EQ=";
     };
 
     nativeBuildInputs = [ unzip ];

pkgs/path-of-building-poe2/default.nix

@@ -0,0 +1,132 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unzip,
+  meson,
+  ninja,
+  pkg-config,
+  qtbase,
+  qttools,
+  wrapQtAppsHook,
+  icoutils,
+  copyDesktopItems,
+  makeDesktopItem,
+  luajit,
+}:
+let
+  data = stdenv.mkDerivation (finalAttrs: {
+    pname = "path-of-building-poe2-data";
+    version = "0.5.0";
+
+    src = fetchFromGitHub {
+      owner = "PathOfBuildingCommunity";
+      repo = "PathOfBuilding-PoE2";
+      rev = "v${finalAttrs.version}";
+      hash = "sha256-/Jh/DZElpS0CKCThDHKTI3gfDFCuD1FxrWVIhrrdMog=";
+    };
+
+    nativeBuildInputs = [ unzip ];
+
+    buildCommand = ''
+      # I have absolutely no idea how this file is generated
+      # and I don't think I want to know. The Flatpak also does this.
+      unzip -j -d $out $src/runtime-win32.zip lua/sha1.lua
+
+      # Install the actual data
+      cp -r $src/src $src/runtime/lua/*.lua $src/manifest.xml $out
+
+      # Pretend this is an official build so we don't get the ugly "dev mode" warning
+      substituteInPlace $out/manifest.xml --replace '<Version' '<Version platform="nixos"'
+      touch $out/installed.cfg
+
+      # Completely stub out the update check
+      chmod +w $out/src/UpdateCheck.lua
+      echo 'return "none"' > $out/src/UpdateCheck.lua
+    '';
+  });
+in
+stdenv.mkDerivation {
+  pname = "path-of-building";
+  version = "${data.version}-unstable-2023-04-09";
+
+  src = fetchFromGitHub {
+    owner = "ernstp";
+    repo = "pobfrontend";
+    rev = "9faa19aa362f975737169824c1578d5011487c18";
+    hash = "sha256-zhw2PZ6ZNMgZ2hG+a6AcYBkeg7kbBHNc2eSt4if17Wk=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    qttools
+    wrapQtAppsHook
+    icoutils
+  ] ++ lib.optional stdenv.hostPlatform.isLinux copyDesktopItems;
+
+  buildInputs = [
+    qtbase
+    luajit
+    luajit.pkgs.lua-curl
+    luajit.pkgs.luautf8
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm555 pobfrontend $out/bin/pobfrontend
+
+    wrestool -x -t 14 ${data.src}/runtime/Path{space}of{space}Building-PoE2.exe -o pathofbuilding.ico
+    icotool -x pathofbuilding.ico
+
+    for size in 16 32 48 256; do
+      mkdir -p $out/share/icons/hicolor/"$size"x"$size"/apps
+      install -Dm 644 pathofbuilding*"$size"x"$size"*.png \
+        $out/share/icons/hicolor/"$size"x"$size"/apps/pathofbuilding.png
+    done
+    rm pathofbuilding.ico
+
+    runHook postInstall
+  '';
+
+  preFixup = ''
+    qtWrapperArgs+=(
+      --set LUA_PATH "$LUA_PATH"
+      --set LUA_CPATH "$LUA_CPATH"
+      --chdir "${data}"
+    )
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "path-of-building";
+      desktopName = "Path of Building";
+      comment = "Offline build planner for Path of Exile";
+      exec = "pobfrontend %U";
+      terminal = false;
+      type = "Application";
+      icon = "pathofbuilding";
+      categories = [ "Game" ];
+      keywords = [
+        "poe"
+        "pob"
+        "pobc"
+        "path"
+        "exile"
+      ];
+      mimeTypes = [ "x-scheme-handler/pob" ];
+    })
+  ];
+
+  passthru.data = data;
+
+  meta = {
+    description = "Offline build planner for Path of Exile";
+    homepage = "https://pathofbuilding.community/";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.k900 ];
+    mainProgram = "pobfrontend";
+    broken = stdenv.hostPlatform.isDarwin; # doesn't find uic6 for some reason
+  };
+}

pkgs/poe-sidekick/default.nix

@@ -0,0 +1,23 @@
+{
+  lib,
+  appimageTools,
+  fetchurl,
+}:
+let
+  version = "2025.901.202";
+  pname = "poe-sidekick";
+
+  src = fetchurl {
+    url = "https://github.com/Sidekick-Poe/Sidekick/releases/download/v${version}/Sidekick-linux-stable.AppImage";
+    hash = "sha256-SMQQcTlRZyc5rt4ZXNFNwBhiPB3WWQfwAIEyprFe2uA=";
+  };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+  extraPkgs = pkgs: [
+    pkgs.dotnet-sdk
+    pkgs.webkitgtk_4_1
+    pkgs.libnotify
+    pkgs.gvfs
+  ];
+}

pkgs/poe-sidekick/web.nix

@@ -0,0 +1,21 @@
+{
+  lib,
+  appimageTools,
+  fetchurl,
+}:
+let
+  version = "2025.901.202";
+  pname = "poe-sidekick-web";
+
+  src = fetchurl {
+    url = "https://github.com/Sidekick-Poe/Sidekick/releases/download/v${version}/Sidekick-linux-web-stable.AppImage";
+    hash = "sha256-DY/Sw4nZxiqpM8aStZ6EhPzNYsdvH8f7Mf+iy6Kr+JI=";
+  };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+  extraPkgs = pkgs: [
+    pkgs.dotnet-sdk
+    pkgs.libnotify
+  ];
+}

pkgs/vintagestory/default.nix

@@ -20,7 +20,7 @@
 }:
 
 stdenv.mkDerivation rec {
-  pname = "vintagestory";
+  pname = "vintagestory-unstable";
   version = "1.20.0-rc.8";
 
   src = fetchurl {