{
  description = "LabMCP - Collection of MCP servers";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      lib = nixpkgs.lib;
      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = lib.genAttrs supportedSystems;
      pkgsFor = system: nixpkgs.legacyPackages.${system};
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = pkgsFor system;
        in
        {
          nixos-options = pkgs.callPackage ./nix/package.nix { src = ./.; };
          hm-options = pkgs.callPackage ./nix/package.nix {
            src = ./.;
            pname = "hm-options-mcp";
            subPackage = "cmd/hm-options";
            mainProgram = "hm-options";
            description = "MCP server for Home Manager options search and query";
          };
          nixpkgs-search = pkgs.callPackage ./nix/package.nix {
            src = ./.;
            pname = "nixpkgs-search";
            subPackage = "cmd/nixpkgs-search";
            mainProgram = "nixpkgs-search";
            description = "Search nixpkgs options and packages";
          };
          lab-monitoring = pkgs.callPackage ./nix/package.nix {
            src = ./.;
            pname = "lab-monitoring";
            subPackage = "cmd/lab-monitoring";
            mainProgram = "lab-monitoring";
            description = "MCP server for Prometheus and Alertmanager monitoring";
          };
          git-explorer = pkgs.callPackage ./nix/package.nix {
            src = ./.;
            pname = "git-explorer";
            subPackage = "cmd/git-explorer";
            mainProgram = "git-explorer";
            description = "Read-only MCP server for git repository exploration";
          };
          default = self.packages.${system}.nixpkgs-search;
        });

      devShells = forAllSystems (system:
        let
          pkgs = pkgsFor system;
        in
        {
          default = pkgs.mkShell {
            buildInputs = with pkgs; [
              go
              gopls
              gotools
              go-tools
              golangci-lint
              govulncheck
              postgresql
              sqlite
            ];

            shellHook = ''
              echo "LabMCP development shell"
              echo "Go version: $(go version)"
            '';
          };
        });

      nixosModules = {
        nixpkgs-search-mcp = { pkgs, ... }: {
          imports = [ ./nix/nixpkgs-search-module.nix ];
          services.nixpkgs-search.package = lib.mkDefault self.packages.${pkgs.system}.nixpkgs-search;
        };
        nixos-options-mcp = { pkgs, ... }: {
          imports = [ ./nix/module.nix ];
          services.nixos-options-mcp.package = lib.mkDefault self.packages.${pkgs.system}.nixos-options;
        };
        hm-options-mcp = { pkgs, ... }: {
          imports = [ ./nix/hm-options-module.nix ];
          services.hm-options-mcp.package = lib.mkDefault self.packages.${pkgs.system}.hm-options;
        };
        lab-monitoring-mcp = { pkgs, ... }: {
          imports = [ ./nix/lab-monitoring-module.nix ];
          services.lab-monitoring.package = lib.mkDefault self.packages.${pkgs.system}.lab-monitoring;
        };
        git-explorer-mcp = { pkgs, ... }: {
          imports = [ ./nix/git-explorer-module.nix ];
          services.git-explorer.package = lib.mkDefault self.packages.${pkgs.system}.git-explorer;
        };
        default = self.nixosModules.nixpkgs-search-mcp;
      };
    };
}